Продолжение, электронный диск на Орион-128 на к537ру17

Какие микросхемы памяти статики ставить на Орион в электронный диск

Продаю платы и наборы микросхем, куплю микросхемы Магазин запчастей ПК Орион-128

ЭЛЕКТРОННЫЙ ДИСК ДЛЯ "ОРИОНА-128"

Журнал: Радио1996 № 5

Электронный диск версия s002 64К+64К

Прототип 1  смотрите  публикация в журнале

Прототип по журналу Радио 1996/05

Программа на Ассемблере  (пример)

Электронный диск версия s002  64К+64К

 И так давно смотрел на этот электронный диск. Вроде инфа есть, есть более совершенный электронный гибридный диск (Дэновский) который работает только под DS DOS. Доя последователей ОР ДОСа.

Попалась платка смотрим ссылку Прототип 1, попалась кое какая инфа.

Решил развести плату, но с несколькими дополнениями (вдохновил Игорь KZ).  Во первых платка вставляется сразу в 2-ва порта F500 и F600, (расстояние между разьемами Х1 и Х3 - выбраны по Экспрессу.   Если не подходит к вашей плате (расстояние отличается от экспресса), нужно отрезать часть платы: см. ниже.

Такая получилась плата, версия S002, плата приехала 05/11/2025

Для других плат может не совпадать, для этого предусмотрена такая конструкция. Желтыми линиями можно отрезать часть платы (правый верхний угол), преимущество дало такое.

1. Освобождается раьзем порта F600,  с разьемом соеденяется  гибким шлейфом. (особенно критично для других плат если расстояние между Х1 и Х3 отличается от экспресса)

2. Соиденение Х1, гибким шлейфом выносится на кросшину, куда вставляется платка расширения портов (порту F600 назначаем другой адрес тем самым освобождаем порт F600 для другой периферии).

Далее изменения коснулись и ромдиска, на плате сразу стоит ПЗУ 27С512 (64К) и раьем Х3.1 - куда можно вставить любой ромдиск с ОР ДОС. Джампером "РОМ/Д Vnutr"  можно переключать внутренний диск (27с512) и внешний разьем Х3.1. , если джампер уставновлен выбирается внутренний ром диск.

Далее изменение коснулось организации питания.

GB1 - внутренняя батарейка

GB2 - внешняя батарейка 3,0-5,0 в.

GB3 - внешнее питание 9-18 в.

И конечно по другому подключен электролит, не как в журнале радио, исключает саморазряд батареек, автор применял элементы 373 довольно мощные.

Пояснение по узлу питания

Узел питания от батарейки отличается от схемы в журнале радио.

Все цепи питания развязаны диодами от контакта C10 (+5В) разьемов портов F500 и F600

С1 - 1000 мкф или более как по журналу радио нужен для горячей замены батарейки.

Rzar  и VD2- подзарядка батарейки

VD4 - развязывает питание от внешней батарейки CB2

Транзистор кт315 и стабилитрон кс156а предназначен для питания от внешнего блока питания, развязан диодом VD5 (номинал резистора  на маске), С2 на входе СВ3 - 100х25в смотри маску. (можно было поставить кр142ен5а (LM7805) - но как то не зашло.

Что не нравится и кажется лишнем можно исключить!!!

Д9б - германиевый диод, средний ток порядка 40 ма, импульсный 125 ма, динамичный ток потребления платой 70 ма

Все конденсаторы керамика 0,01-0,1 мкф.

Сборка

Плата экспресса со вставленным электронным диском

В плату электронного диска вставлен Ром Диск на 27с512

Прототип 1

И так 03/06/2024 появилась информация и гербер платы по электронному диску

Скачать архив, в архиве лайка, схема из журнала, описание, прога на ассемблере из журнала

Подробнее читаем в предыдущей статье

Плата

Программа на Ассемблере  пример.

Прога на ассемблере с комментариями от Вадима

Программа в машинных кодах скачать

Прога в текстовом файле с комментариями от Вадима

; трансляция на сайте https://caglrc.cc/~svo/i8080/
; 8080 assembler code
.hexfile test.hex
.binfile test.com
; try "hex" for downloading in hex format
.download bin

;==============================================================
; Драйвер ром диска на статик рам 537 РУ 17 =
; Схема из Радио №5 1996 г. стр 25 =
;==============================================================


;=============== ордос шапка ==================================
.ORG 0ABF0H ;адрес посадки драйвера минус
;10h байт на шапку
;ордос файла

db 'ramromd$' ;имя файла ордос + признак
;запускаемого
;файла
dw 0ac00h ;адрес посадки файла
dw endaddr-begaddr+1
;размер тела файла
db 0 ;флаг защиты от записи
dw 0 ;служебные ячейки ордос
db 0 ;служебные ячейки ордос

;================ код драйвера =================================
;AC00 - патч ОРДОС в ОЗУ и передача ей управления
;ВЕРСИЯ ОРДОС НЕ ПРОВЕРЯЕТСЯ !!!!!!!!!!!!!!!!!!

begaddr:LXI H,PRD ;НОВЫЙ АДРЕС ПОДПРОГРАММЫ
;ЧТЕНИЯ БАЙТА ИЗ ДОПОЛНИТЕЛЬНОЙ
;СТРАНИЦЫ ОЗУ (F836)

SHLD 0BB3AH ;патчим ОРДОС (контроль версий
;!!!)
SHLD 0BEB8H ;патчим ОРДОС (контроль версий
;!!!)

LXI H,PWR ;НОВЫЙ АДРЕС ПОДПРОГРАММЫ
;ЗАПИСИ БАЙТА
;В ДОПОЛНИТЕЛЬНЫЕ СТРАНИЦЫ
;ОЗУ (F839)


SHLD 0BB53H ;патчим ОРДОС (контроль версий
;!!!)

SHLD 0BED6H ;патчим ОРДОС (контроль версий
;!!!)
JMP 0bffdh ;ПЕРЕДАЧА УПРАВЛЕНИЯ ORDOS

;===== п/п чтения с доп. страницы ОЗУ, вызывается из ORDOS ====
; в акк. номер страницы ОЗУ
; при попытке чтения с 3 страницы ОЗУ переход на чтение
; рамром диска
; иначе читаем байт в рег. С из выбранной страницы ОЗУ

PRD: CPI 03H ;ЕСЛИ ЧТЕНИЕ СО СТРАНИЦЫ 03 ОЗУ
JZ RDB ;(DISK D), ТО переход НА
;ПОДПРОГРАММУ
;ЧТЕНИЯ БАЙТА С S.DISK

CALL 0f836h ;ИНАЧЕ читаем СТРАНИЦу ОЗУ
;как обычно
RET ;можно просто jmp 0f836h

;===== п/п записи в доп. страницы ОЗУ, вызывается из ORDOS ====
; в акк. номер страницы ОЗУ
; при попытке записи в 3 страницы ОЗУ переход на запись
; рамром диска
; иначе пишем байт из рег. С в выбранную страницу ОЗУ
PWR: CPI 03H ;ЕСЛИ ЗАПИСЬ В СТРАНИЦУ 03 ОЗУ
JZ WRB ;(DISK D), ТО ПЕРЕХОД НА
;ПОДПРОГРАММУ
;ЗАПИСИ БАЙТА В S.DISK
CALL 0F839H ;ИНАЧЕ пишем СТРАНИЦу ОЗУ
;как обычно
RET ;можно просто jmp 0f839h

;========= Чтение байта из рамром диска =======================
RDB: CALL KM ;ПОДПРОГРАММА ВЫБОРА
;МИКРОСХЕМ RAM СОГЛАСНО АДРЕСУ

LXI H,0F603H ;ПРОГРАММИРОВАНИЕ ПОРТА

MVI M,90H ;НА ЧТЕНИЕ
DCX H
DCX H ;В HL число 0F601h
MOV M,B ;ЗАПИСЬ КОДА, ОПРЕДЕЛЯЮЩЕГО
;МИКРОСХЕМУ RAM
INX H ;В HL число 0F602h
MVI M,40H ;ВЫСТАВИТЬ СИГНАЛ ЧТЕНИЯ RD
MVI M,0C0H ;СНЯТЬ ХРАНЕНИЕ CS2=1
LDA 0F600H ;СЧИТАТЬ БАЙТ
MOV C,A ;СОХРАНИТЬ ПОЛУЧЕННЫЙ
;БАЙТ В рег. С
MVI M,40H ;ВЫСТАВИТЬ ХРАНЕНИЕ CS2=0
XRA M ;СНЯТЬ СИГНАЛ RD
DCX H ;В HL байт 0F601h
XRA M ;ПЕРЕВОД ДИСКА S В ОСНОВНОЙ
RET ;РЕЖИМ ХРАНЕНИЯ

;========= Запись байта в рамром диск =======================
WRB: CALL KM ;ПОДПРОГРАММа ВЫБОРА МИКРО
;СХЕМ RAM СОГЛАСНО АДРЕСУ

LXI H,0F603H ;ПРОГРАММИРОВАНИЕ ПОРТА
MVI M,80H ;НА ЗАПИСЬ
LXI H,0F600H ;ЗАПИСЬ ДАННЫХ В ПОРТ
MOV M,C
INX H ;В HL число 0F601h
MOV M,B ;ЗАПИСЬ КОДА, ОПРЕДЕЛЯЮЩЕГО
;МИКРОСХЕМУ RAM
INX H ;В HL число 0F602h
MVI M,80H ;СНЯТЬ ХРАНЕНИЕ CS2=1
XRA M ;ВОССТАНОВИТЬ ХРАНЕНИЕ CS2=0
DCX H ;В HL число 0F601h
XRA M ;ПЕРЕВОД ВСЕХ МИКРОСХЕМ RAM
RET ;В ОСНОВНОЙ РЕЖИМ ХРАНЕНИЯ

;====== ПОДПРОГРАММа ВЫБОРА МИКРОСХЕМ RAM СОГЛАСНО АДРЕСУ ===
KM: MVI B,0FEH ;КОД FE СООТВЕТСТВУЕТ ПОДКЛЮ
MOV A,H ;ЧЕНИЮ ПЕРВОЙ МИКРОСХЕМЫ
CPI 20H ;HL<207
JC WRA ;ЕСЛИ ДА, ТО НА ПОДПРОГРАММУ
;ЗАПИСИ АДРЕСА В ПОРТ F500

CALL CEO ;ЕСЛИ НЕТ, ТО НА ПОДПРОГРАММУ
CPI 40H ;ПЕРЕКЛОЧЕНИЯ НА СЛЕДУЩУЮ
JC WRA ;МИКРОСХЕМУ RAM

CALL CEO
CPI 60H
JC WRA

CALL CEO
CPI 80H
JC WRA

CALL CEO
CPI 0A0H
JC WRA

CALL CEO
CPI 0C0H
JC WRA
CALL CEO
CPI 0E0H ;HL < Е07
JC WRA ;ЕСЛИ <, ТО НА ПОДПРОГРАММу
;ЗАПИСИ АДРЕСА В ПОРТ F500
CALL CEO ;ЕСЛИ >, ТО НА ПОДПРОГРАММУ
;ПЕРЕКЛЮЧЕНИЯ МИКРОСХЕМ RAM
;====== ПОДПРОГРАММА ЗАПИСИ АДРЕСА В ПОРТ F500 ============
WRA: PUSH H ;WRA: ПОДПРОГРАММА УСТАНОВКИ
LXI H,0F503H ;АДРЕСА HA АДРЕСНОЙ ШИНЕ
MVI M,90h ;МИКРОСХЕМ RAM ПОСРЕДСТВОМ
POP H ;ПОРТА F500
SHLD 0F501H
RET
;
CEO: MOV A,B ;СЕО: ПОДПРОГРАММА ИЗМЕНЕНИЯ
RLC ;КОДА, ОПРЕДЕЛЯЩЕГО МИКРО
MOV B,A ;СХЕМУ, НА СЛЕДУЩИЙ
MOV A,H
endaddr:RET

end

Конец проги в текстовом файле с комментариями от Вадима

Прототип по журналу Радио 1996/05

Я. ДМИТРИЕНКО, г. Кишинев, Молдова

Предлагаемое вниманию читателей устройство - электронный диск с объемом памяти 64 Кбайт - позволяет хранить записанную в него информацию неограниченно долго при обеспечении надежного питания. Обслуживающая его программа S_DISK рассчитана на работу с ORDOS версии 4.0, при необходимости ее можно использовать и с ORDOS версии 2.4, внеся в программу небольшие изменения, приведенные в статье.

Принципиальная схема электронного диска (далее диск S) приведена на рисунке, а программа S_DISK - в табл. 1. Как видно, устройство представляет собой набор из восьми КМОП-микросхем статического ОЗУ серии К537. Подключают его к портам F500 и F600 компьютера (первый из них - порт ROM -диска - использован в качестве адресной шины диска S , а его шина данных, управление чтением/записью, а также переключение микросхем подключены к параллельному порту F600). Режим хранения информации определяется состоянием сигнала CS 1, его уровень логической 1 соответствует хранению, а логического 0 - снятию хранения. Для более надежного запрета на доступ к микросхемам диска, находящимся в режиме хранения, одновременно со сменой уровня сигнала с 0 на 1 на входе CS1 изменяется таким же образом и уровень сигнала на входе СЕ0 (выводы 20 и 22 соединены вместе).

Остальное читаем в предыдущей статье

Журнал Радио №5 1996 год.

Гибридный электронный диск под ДС ДОС

Так же электронный диск можно сделать на DS1250Y

Купить платы, наборы микросхем на Орион-128, КР565РУ5В, КР565ру7В, к565ру5г AU, к565ру7г Au в позолоте, куплю микросхемы